First commit of partial RosettaCode contents.

Pushing this for testing purposes. Lots of work still needed.

Task/Entropy/REXX/entropy-2.rexx

@@ -0,0 +1,30 @@
+/*REXX program calculates the information entropy  for a given char str.*/
+numeric digits 30                      /*use thirty digits for precision*/
+parse arg $;         if $=='' then $=1223334444  /*obtain optional input*/
+n=0;  @.=0;  L=length($);  $$=
+
+      do j=1  for L;  _=substr($,j,1)  /*process each character in $ str*/
+      if @._==0  then do;   n=n+1      /*if unique,  bump char counter. */
+                      $$=$$ || _       /*add this character to the list.*/
+                      end
+      @._ = @._+1                      /*keep track of this char count. */
+      end   /*j*/
+sum=0                                  /*calc info entropy for each char*/
+      do i=1  for n;  _=substr($$,i,1) /*obtain a char from unique list.*/
+      sum=sum  -  @._/L  * log2(@._/L) /*add (negatively) the entropies.*/
+      end   /*i*/
+
+say ' input string: ' $
+say 'string length: ' L
+say ' unique chars: ' n ;       say
+say 'the information entropy of the string ──► ' format(sum,,12)  " bits."
+exit                                   /*stick a fork in it, we're done.*/
+/*──────────────────────────────────LOG2 subroutine─────────────────────*/
+log2: procedure; parse arg x 1 xx;    ig= x>1.5;   is=1-2*(ig\==1);   ii=0
+numeric digits digits()+5      /* [↓] precision of E must be > digits().*/
+e=2.7182818284590452353602874713526624977572470936999595749669676277240766303535
+    do  while  ig & xx>1.5 | \ig&xx<.5;   _=e;     do k=-1;  iz=xx* _**-is
+    if k>=0 & (ig & iz<1 | \ig&iz>.5)     then leave;  _=_*_;  izz=iz; end
+    xx=izz;  ii=ii+is*2**k;  end;         x=x* e**-ii-1;  z=0;  _=-1;  p=z
+      do k=1;  _=-_*x;  z=z+_/k;  if z=p  then leave;  p=z;  end  /*k*/
+    r=z+ii;  if arg()==2  then return r;  return r/log2(2,0)

Task/Entropy/REXX/entropy.rexx

@@ -0,0 +1,84 @@
+/* Rexx ***************************************************************
+* 28.02.2013 Walter Pachl
+* 12.03.2013 Walter Pachl  typo in log corrected. thanx for testing
+**********************************************************************/
+s="1223334444"
+occ.=0
+n=0
+Do i=1 To length(s)
+  c=substr(s,i,1)
+  occ.c=occ.c+1
+  n=n+1
+  End
+do c=1 To 4
+  p.c=occ.c/n
+  say c p.c
+  End
+e=0
+Do c=1 To 4
+  e=e+p.c*log(p.c,,2)
+  End
+Say 'Entropy of' s 'is' (-e)
+Exit
+
+log: Procedure
+/***********************************************************************
+* Return log(x) -- with specified precision and a specified base
+* Three different series are used for the ranges  0 to 0.5
+*                                                 0.5 to 1.5
+*                                                 1.5 to infinity
+* 03.09.1992 Walter Pachl
+***********************************************************************/
+  Parse Arg x,prec,b
+  If prec='' Then prec=9
+  Numeric Digits (2*prec)
+  Numeric Fuzz   3
+  Select
+    When x<=0 Then r='*** invalid argument ***'
+    When x<0.5 Then Do
+      z=(x-1)/(x+1)
+      o=z
+      r=z
+      k=1
+      Do i=3 By 2
+        ra=r
+        k=k+1
+        o=o*z*z
+        r=r+o/i
+        If r=ra Then Leave
+        End
+      r=2*r
+      End
+    When x<1.5 Then Do
+      z=(x-1)
+      o=z
+      r=z
+      k=1
+      Do i=2 By 1
+        ra=r
+        k=k+1
+        o=-o*z
+        r=r+o/i
+        If r=ra Then Leave
+        End
+      End
+    Otherwise /* 1.5<=x */ Do
+      z=(x+1)/(x-1)
+      o=1/z
+      r=o
+      k=1
+      Do i=3 By 2
+        ra=r
+        k=k+1
+        o=o/(z*z)
+        r=r+o/i
+        If r=ra Then Leave
+        End
+      r=2*r
+      End
+    End
+  If b<>'' Then
+    r=r/log(b)
+  Numeric Digits (prec)
+  r=r+0
+  Return r