June 2018 Update

Task/Generator-Exponential/Lingo/generator-exponential-1.lingo

@@ -0,0 +1,11 @@
+squares = script("generator.power").new(2)
+cubes   = script("generator.power").new(3)
+filter  = script("generator.filter").new(squares, cubes)
+filter.skip(20)
+res = []
+i = 0
+repeat while filter.exec(res)
+    i = i + 1
+    if i>10 then exit repeat
+    put res[1]
+end repeat

Task/Generator-Exponential/Lingo/generator-exponential-2.lingo

@@ -0,0 +1,23 @@
+property _exp
+property _index
+
+-- @constructor
+on new (me, e)
+    me._exp = e
+    me._index = 0
+    return me
+end
+
+on exec (me, input)
+    me._index = me._index+1
+    input[1] = integer(power(me._index, me._exp))
+    return TRUE
+end
+
+on skip (me, steps)
+    me._index = me._index + steps
+end
+
+on reset (me)
+    me._index = 0
+end

Task/Generator-Exponential/Lingo/generator-exponential-3.lingo

@@ -0,0 +1,43 @@
+property _genv
+property _genf
+
+-- @constructor
+on new (me, genv, genf)
+    me._genv = genv
+    me._genf = genf
+    return me
+end
+
+on exec (me, input)
+    repeat while TRUE
+        me._genv.exec(input)
+        v = input[1]
+        ok = TRUE
+        me._genf.reset() -- reset filter generator
+        repeat while TRUE
+            me._genf.exec(input)
+            f = input[1]
+            if f>v then exit repeat
+            if f=v then
+                ok=FALSE
+                exit repeat
+            end if
+        end repeat
+        if ok then
+            input[1] = v
+            exit repeat
+        end if
+    end repeat
+    return TRUE
+end
+
+on skip (me, steps)
+    repeat with i = 1 to steps
+        me.exec([])
+    end repeat
+end
+
+on reset (me)
+    me._genv.reset()
+    me._genf.reset()
+end