Data update

Task/Feigenbaum-constant-calculation/REXX/feigenbaum-constant-calculation-2.rexx

@@ -0,0 +1,63 @@
+arg n; if n = '' then n = 30; numeric digits n
+parse version version; say version; glob. = ''
+say 'First Fiegenbaum constant, correct to about 11 decimals'
+say 'Using algorithm cf RosettaCode'
+say
+call time('r'); a = Original(); e = format(time('e'),,3)
+say 'Original  ' a '('e 'seconds)'
+call time('r'); a = Optimized(); e = format(time('e'),,3)
+say 'Optimized ' a '('e 'seconds)'
+call time('r'); a = TrueValue(); e = format(time('e'),,3)
+say 'True value' a '('e 'seconds)'
+exit
+
+Original:
+procedure expose glob.
+/* Outer 2 loops with a fixed value */
+numeric digits digits()+2
+im = 20; jm = 10
+a1 = 1; a2 = 0; d1 = 3.2
+do i = 2 to im
+   a = a1 + (a1-a2)/d1
+   do j = 1 to jm
+      x = 0; y = 0
+      do k = 1 to 2**i
+         y = 1 - 2*x*y; x = a - x*x
+      end
+      a = a - x/y
+   end
+   d = (a1-a2) / (a-a1)
+   parse value d a1 a with d1 a2 a1
+end
+numeric digits digits()-2
+return d+0
+
+Optimized:
+procedure expose glob.
+/* Center loop stops on achieving desired accuracy */
+numeric digits digits()+4; numeric fuzz 4
+/* Only outer loop maximum */
+im = 20
+a1 = 1; a2 = 0; d1 = 3.2
+do i = 2 to im
+   a = a1 + (a1-a2)/d1; v = 0
+   do forever
+      x = 0; y = 0
+      do 2**i
+         y = 1 - 2*x*y; x = a - x*x
+      end
+      a = a - x/y
+/* Stop second loop when a does not change anymore */
+      if a = v then
+         leave
+      v = a
+   end
+   d = (a1-a2) / (a-a1)
+   parse value d a1 a with d1 a2 a1
+end
+numeric digits digits()-4
+return d+0
+
+TrueValue:
+procedure expose glob.
+return 4.66920160910299067185320382046620161725818557747576863274565134300413433021131473713868974402394801381716+0