all tasks

Task/Text-processing-1/J/text-processing-1-1.j

@@ -0,0 +1,14 @@
+  load 'files'
+  parseLine=: 10&({. ,&< (_99&".;._1)@:}.)  NB. custom parser
+  summarize=: # , +/ , +/ % #               NB. count,sum,mean
+  filter=: #~ 0&<                           NB. keep valid measurements
+
+  'Dates dat'=: |: parseLine;._2 CR -.~ fread jpath '~temp/readings.txt'
+  Vals=:  (+: i.24){"1 dat
+  Flags=: (>: +: i.24){"1 dat
+  DailySummary=: Vals summarize@filter"1 Flags
+  RunLengths=: ([: #(;.1) 0 , }. *. }:) , 0 >: Flags
+   ]MaxRun=: >./ RunLengths
+589
+   ]StartDates=: Dates {~ (>:@I.@e.&MaxRun (24 <.@%~ +/)@{. ]) RunLengths
+1993-03-05

Task/Text-processing-1/J/text-processing-1-2.j

@@ -0,0 +1,11 @@
+formatDailySumry=: dyad define
+  labels=. , ];.2 'Line: Accept: Line_tot: Line_avg: '
+  labels , x ,. 7j0 10j3 10j3 ": y
+)
+formatFileSumry=: dyad define
+  labels=. ];.2 'Total: Readings: Average: '
+  sumryvals=. (, %/) 1 0{ +/y
+  out=. labels ,. 12j3 12j0 12j3 ":&> sumryvals
+  'maxrun dates'=. x
+  out=. out,LF,'Maximum run(s) of ',(": maxrun),' consecutive false readings ends at line(s) starting with date(s): ',dates
+)

Task/Text-processing-1/J/text-processing-1-3.j

@@ -0,0 +1,13 @@
+   (_4{.Dates) formatDailySumry _4{. DailySummary
+Line:     Accept:   Line_tot: Line_avg:
+2004-12-28     23    77.800     3.383
+2004-12-29     23    56.300     2.448
+2004-12-30     23    65.300     2.839
+2004-12-31     23    47.300     2.057
+
+   (MaxRun;StartDates) formatFileSumry DailySummary
+Total:     1358393.400
+Readings:       129403
+Average:        10.497
+
+Maximum run(s) of 589 consecutive false readings ends at line(s) starting with date(s): 1993-03-05