March 2014 update

Task/Priority-queue/AutoHotkey/priority-queue-1.ahk

@@ -0,0 +1,60 @@
+;-----------------------------------
+PQ_TopItem(Queue,Task:=""){					; remove and return top priority item
+	TopPriority := PQ_TopPriority(Queue)
+	for T, P in Queue
+		if (P = TopPriority) && ((T=Task)||!Task)
+			return T , Queue.Remove(T)
+	return 0
+}
+;-----------------------------------
+PQ_AddTask(Queue,Task,Priority){				; insert and return new task
+	for T, P in Queue
+		if (T=Task) || !(Priority && Task)
+			return 0
+	return Task,	Queue[Task] := Priority
+}
+;-----------------------------------
+PQ_DelTask(Queue, Task){					; delete and return task
+	for T, P in Queue
+		if (T = Task)
+			return Task,	Queue.Remove(Task)
+}
+;-----------------------------------
+PQ_Peek(Queue){							; peek and return top priority task(s)
+	TopPriority := PQ_TopPriority(Queue)
+	for T, P in Queue
+		if (P = TopPriority)
+			PeekList .= (PeekList?"`n":"") "`t" T
+	return PeekList
+}
+;-----------------------------------
+PQ_Check(Queue,Task){						; check task and return its priority
+	for T, P in Queue
+		if (T = Task)
+			return P
+	return 0
+}
+;-----------------------------------
+PQ_Edit(Queue,Task,Priority){					; Update task priority and return its new priority
+	for T, P in Queue
+		if (T = Task)
+			return Priority,	Queue[T]:=Priority
+	return 0
+}
+;-----------------------------------
+PQ_View(Queue){							; view current Queue
+	for T, P in Queue
+		Res .= P " : " T "`n"
+	Sort, Res, FMySort
+	return "Priority Queue=`n" Res
+}
+MySort(a,b){
+	RegExMatch(a,"(\d+) : (.*)", x), RegExMatch(b,"(\d+) : (.*)", y)
+	return x1>y1?1:x1<y1?-1: x2>y2?1:x2<y2?-1: 0
+}
+;-----------------------------------
+PQ_TopPriority(Queue){						; return queue's top priority
+	for T, P in Queue
+		TopPriority := TopPriority?TopPriority:P	, TopPriority := TopPriority<P?TopPriority:P
+	return, TopPriority
+}

Task/Priority-queue/AutoHotkey/priority-queue-2.ahk

@@ -0,0 +1,22 @@
+data =
+(
+3	Clear drains
+1	test
+4	Feed cat
+5	Make tea
+1	Solve RC tasks
+2	Tax return
+)
+PQ:=[] 								; Create Priority Queue PQ[Task, Priority]
+loop, parse, data, `n, `r
+	F:= StrSplit(A_LoopField, "`t")	, PQ[F[2]] := F[1]
+PQ_View(PQ)
+MsgBox, 262208,, % "Top Priority item(s)=`n" 			PQ_Peek(PQ)	"`n`n" PQ_View(PQ)
+MsgBox, 262208,, % "Add : " 					PQ_AddTask(PQ, "AutoHotkey", 2)	"`n`n" PQ_View(PQ)
+MsgBox, 262208,, % "Remove Top Item : " 			PQ_TopItem(PQ) "`n`n" PQ_View(PQ)
+MsgBox, 262208,, % "Remove specific top item : " 		PQ_TopItem(PQ,"test") "`n`n" PQ_View(PQ)
+MsgBox, 262208,, % "Delete Item : " 				PQ_DelTask(PQ, "Clear drains")	"`n`n" PQ_View(PQ)
+MsgBox, 262208,, % (Task:="Tax return") " new priority = "	PQ_Edit(PQ,task, 7)	"`n`n" PQ_View(PQ)
+MsgBox, 262208,, % (Task:="Feed cat")  " priority = " 		PQ_Check(PQ,task)"`n`n" PQ_View(PQ)
+^Esc::
+ExitApp