Data update

Task/Peano-curve/ALGOL-68/peano-curve.alg

@@ -0,0 +1,60 @@
+BEGIN # Peano Curve in SVG                                                   #
+      # uses the RC Algol 68 L-System library for the L-System evaluation &  #
+      # interpretation                                                       #
+
+    PR read "lsystem.incl.a68" PR               # include L-System utilities #
+
+    PROC peano curve = ( STRING fname, INT size, length, order, init x, init y )VOID:
+         IF FILE svg file;
+            BOOL open error := IF open( svg file, fname, stand out channel ) = 0
+                               THEN
+                                   # opened OK - file already exists and     #
+                                   #             will be overwritten         #
+                                   FALSE
+                               ELSE
+                                   # failed to open the file                 #
+                                   # - try creating a new file               #
+                                   establish( svg file, fname, stand out channel ) /= 0
+                               FI;
+            open error
+         THEN                                      # failed to open the file #
+            print( ( "Unable to open ", fname, newline ) );
+            stop
+         ELSE                                               # file opened OK #
+
+            REAL x     := init x;
+            REAL y     := init y;
+            INT  angle := 90;
+            put( svg file, ( "<svg xmlns='http://www.w3.org/2000/svg' width='"
+                           , whole( size, 0 ), "' height='", whole( size, 0 ), "'>"
+                           , newline, "<rect width='100%' height='100%' fill='white'/>"
+                           , newline, "<path stroke-width='1' stroke='black' fill='none' d='"
+                           , newline, "M", whole( x, 0 ), ",", whole( y, 0 ), newline
+                           )
+               );
+
+            LSYSTEM ssc = ( "L"
+                          , ( "L" -> "LFRFL-F-RFLFR+F+LFRFL"
+                            , "R" -> "RFLFR+F+LFRFL-F-RFLFR"
+                            )
+                          );
+            STRING curve = ssc EVAL order;
+            curve INTERPRET ( ( CHAR c )VOID:
+                              IF   c = "F" THEN
+                                  x +:= length * cos( angle * pi / 180 );
+                                  y +:= length * sin( angle * pi / 180 );
+                                  put( svg file, ( " L", whole( x, 0 ), ",", whole( y, 0 ), newline ) )
+                              ELIF c = "+" THEN
+                                  angle +:= 90 MODAB 360
+                              ELIF c = "-" THEN
+                                  angle -:= 90 MODAB 360
+                              FI
+                            );
+
+            put( svg file, ( "'/>", newline, "</svg>", newline ) );
+            close( svg file )
+         FI # sierpinski square # ;
+
+    peano curve( "peano.svg", 1200, 12, 3, 50, 50 )
+
+END

Task/Peano-curve/EasyLang/peano-curve.easy

@@ -0,0 +1,34 @@
+proc lsysexp level . axiom$ rules$[] .
+   for l to level
+      an$ = ""
+      for c$ in strchars axiom$
+         for i = 1 step 2 to len rules$[]
+            if rules$[i] = c$
+               c$ = rules$[i + 1]
+               break 1
+            .
+         .
+         an$ &= c$
+      .
+      swap axiom$ an$
+   .
+.
+proc lsysdraw axiom$ x y ang . .
+   linewidth 0.3
+   move x y
+   for c$ in strchars axiom$
+      if c$ = "F"
+         x += cos dir
+         y += sin dir
+         line x y
+      elif c$ = "-"
+         dir -= ang
+      elif c$ = "+"
+         dir += ang
+      .
+   .
+.
+axiom$ = "L"
+rules$[] = [ "L" "LFRFL-F-RFLFR+F+LFRFL" "R" "RFLFR+F+LFRFL-F-RFLFR" ]
+lsysexp 4 axiom$ rules$[]
+lsysdraw axiom$ 5 90 90