tasks a-s

Task/Execute-a-Markov-algorithm/J/execute-a-markov-algorithm-1.j

@@ -0,0 +1,30 @@
+require'strings regex'
+
+markovLexer =:  verb define
+  rules =.  LF cut TAB&=`(,:&' ')}y
+  rules =.  a: -.~ (dltb@:{.~ i:&'#')&.> rules
+  rules =.  0 _1 {"1 '\s+->\s+' (rxmatch rxcut ])S:0 rules
+  (,. ] (}.&.>~ ,. ]) ('.'={.)&.>)/ |: rules
+)
+
+
+replace     =:  dyad define
+  'index patternLength replacement'=.  x
+  'head tail' =.  index split y
+  head, replacement, patternLength }. tail
+)
+
+matches     =:  E. i. 1:
+
+markov      =:  dyad define
+  ruleIdx =. 0 [ rules =.  markovLexer x
+  while. ruleIdx < #rules do.
+    'pattern replacement terminating' =. ruleIdx { rules
+    ruleIdx =. 1 + ruleIdx
+    if. (#y) > index =. pattern matches y do.
+      y =. (index ; (#pattern) ; replacement) replace y
+      ruleIdx =. _ * terminating
+    end.
+  end.
+  y
+)

Task/Execute-a-Markov-algorithm/J/execute-a-markov-algorithm-2.j

@@ -0,0 +1,13 @@
+   m1 =. noun define
+	# This rules file is extracted from Wikipedia:
+	# http://en.wikipedia.org/wiki/Markov_Algorithm
+	A -> apple
+	B -> bag
+	S -> shop
+	T -> the
+	the shop -> my brother
+	a never used -> .terminating rule
+)
+
+   m1 markov 'I bought a B of As from T S.'
+I bought a bag of apples from my brother.