September 2017 Update

Task/Move-to-front-algorithm/Jq/move-to-front-algorithm-1.jq

@@ -0,0 +1,19 @@
+# Input is the string to be encoded, st is the initial symbol table (an array)
+# Output: the encoded string (an array)
+def m2f_encode(st):
+  reduce explode[] as $ch
+    ( [ [], st];                  # state: [ans, st]
+      (.[1]|index($ch)) as $ix
+      | .[1] as $st
+      | [ (.[0] + [ $ix ]),  [$st[$ix]] + $st[0:$ix] + $st[$ix+1:] ] )
+  | .[0];
+
+# Input should be the encoded string (an array)
+# and st should be the initial symbol table (an array)
+def m2f_decode(st):
+  reduce .[] as $ix
+    ( [ [], st];                  # state: [ans, st]
+      .[1] as $st
+      | [ (.[0] + [ $st[$ix] ]),  [$st[$ix]] + $st[0:$ix] + $st[$ix+1:] ] )
+  | .[0]
+  | implode;

Task/Move-to-front-algorithm/Jq/move-to-front-algorithm-2.jq

@@ -0,0 +1,9 @@
+("abcdefghijklmnopqrstuvwxyz" | explode) as $ST
+  | ("broood", "bananaaa", "hiphophiphop")
+  | . as $string
+  | m2f_encode($ST)
+  | . as $encoded
+  | m2f_decode($ST) as $decoded
+  | if $string == $decoded then "\($string) => \($encoded) => \($decoded)"
+    else "INTERNAL ERROR: encoding of \($string) => \($encoded) => \($decoded)"
+    end

Task/Move-to-front-algorithm/Jq/move-to-front-algorithm-3.jq

@@ -0,0 +1,4 @@
+$ jq -r -n -f move_to_front.jq
+broood => [1,17,15,0,0,5] => broood
+bananaaa => [1,1,13,1,1,1,0,0] => bananaaa
+hiphophiphop => [7,8,15,2,15,2,2,3,2,2,3,2] => hiphophiphop