Add tasks for all the new languages

Task/Animation/Phix/animation.phix

@@ -0,0 +1,33 @@
+include arwen.ew
+
+string hw = "Hello World! "
+integer direction = 1
+
+constant main = create(Window, "Animation", 0, 0, 20, 20, 300, 150, 0),
+         label = create(Label,hw,0,main,65,40,200,40,0),
+         MainTimer = createTimer()
+    setFont(label, "Verdana", 18, Normal)
+    removeStyle(main,WS_THICKFRAME+WS_MINIMIZEBOX+WS_MAXIMIZEBOX)
+
+function mainHandler(integer id, integer msg, atom wParam, object lParam)
+    if msg=WM_SHOWWINDOW then
+        startTimer(MainTimer,main,160)
+    elsif msg=WM_TIMER then
+        if direction then
+            hw = hw[$]&hw[1..-2]
+        else
+            hw = hw[2..$]&hw[1]
+        end if
+        setText(label,hw)
+    elsif msg=WM_LBUTTONUP then
+        direction = 1-direction
+    elsif msg=WM_CHAR
+      and wParam=VK_ESCAPE then
+        closeWindow(main)
+        if id or object(lParam) then end if -- suppress warnings
+    end if
+    return 0
+end function
+setHandler({main},routine_id("mainHandler"))
+
+WinMain(main, SW_NORMAL)