Data commit

Task/Anagrams/AWK/anagrams-1.awk

@@ -0,0 +1,26 @@
+# JUMBLEA.AWK - words with the most duplicate spellings
+# syntax: GAWK -f JUMBLEA.AWK UNIXDICT.TXT
+{   for (i=1; i<=NF; i++) {
+      w = sortstr(toupper($i))
+      arr[w] = arr[w] $i " "
+      n = gsub(/ /,"&",arr[w])
+      if (max_n < n) { max_n = n }
+    }
+}
+END {
+    for (w in arr) {
+      if (gsub(/ /,"&",arr[w]) == max_n) {
+        printf("%s\t%s\n",w,arr[w])
+      }
+    }
+    exit(0)
+}
+function sortstr(str,  i,j,leng) {
+    leng = length(str)
+    for (i=2; i<=leng; i++) {
+      for (j=i; j>1 && substr(str,j-1,1) > substr(str,j,1); j--) {
+        str = substr(str,1,j-2) substr(str,j,1) substr(str,j-1,1) substr(str,j+1)
+      }
+    }
+    return(str)
+}

Task/Anagrams/AWK/anagrams-2.awk

@@ -0,0 +1,17 @@
+#!/bin/gawk -f
+
+{   patsplit($0, chars, ".")
+    asort(chars)
+    sorted = ""
+    for (i = 1; i <= length(chars); i++)
+	sorted = sorted chars[i]
+
+    if (++count[sorted] > countMax) countMax++
+    accum[sorted] = accum[sorted] " " $0
+}
+
+END {
+    for (i in accum)
+	if (count[i] == countMax)
+	    print substr(accum[i], 2)
+}