Data commit

Task/Binary-search/Maple/binary-search-1.maple

@@ -0,0 +1,15 @@
+BinarySearch := proc( A, value, low, high )
+        description "recursive binary search";
+        if high < low then
+                FAIL
+        else
+                local mid := iquo( high + low, 2 );
+                if A[ mid ] > value then
+                        thisproc( A, value, low, mid - 1 )
+                elif A[ mid ] < value then
+                        thisproc( A, value, mid + 1, high )
+                else
+                        mid
+                end if
+        end if
+end proc:

Task/Binary-search/Maple/binary-search-2.maple

@@ -0,0 +1,17 @@
+BinarySearch := proc( A, value )
+        description "iterative binary search";
+        local low, high;
+
+        low, high := ( lowerbound, upperbound )( A );
+        while low <= high do
+                local mid := iquo( low + high, 2 );
+                if A[ mid ] > value then
+                        high := mid - 1
+                elif A[ mid ] < value then
+                        low := mid + 1
+                else
+                        return mid
+                end if
+        end do;
+        FAIL
+end proc:

Task/Binary-search/Maple/binary-search-3.maple

@@ -0,0 +1,17 @@
+> N := 10:
+> P := [seq]( ithprime( i ), i = 1 .. N ):
+> BinarySearch( P, 12, 1, N ); # recursive version
+                                  FAIL
+
+> BinarySearch( P, 13, 1, N ); # recursive version
+                                   6
+
+> BinarySearch( Array( P ), 13, 1, N ); # make P into an array
+                                   6
+
+> PP := Array( -2 .. 7, P ): # check it works if the array is not 1-based.
+> BinarySearch( PP, 13 ); # iterative version
+                                   3
+
+> PP[ 3 ];
+                                   13