Data commit

Task/CSV-to-HTML-translation/J/csv-to-html-translation-1.j

@@ -0,0 +1,22 @@
+require 'strings tables/csv'
+encodeHTML=: ('&';'&amp;';'<';'&lt;';'>';'&gt;')&stringreplace
+
+tag=: adverb define
+  'starttag endtag'=.m
+  (,&.>/)"1 (starttag , ,&endtag) L:0 y
+)
+
+markupCells=:    ('<td>';'</td>') tag
+markupHdrCells=: ('<th>';'</th>') tag
+markupRows=:     ('<tr>';'</tr>',LF) tag
+markupTable=:    (('<table>',LF);'</table>') tag
+
+makeHTMLtablefromCSV=: verb define
+  0 makeHTMLtablefromCSV y             NB. default left arg is 0 (no header row)
+:
+  t=. fixcsv encodeHTML y
+  if. x do. t=. (markupHdrCells@{. , markupCells@}.) t
+      else. t=. markupCells t
+  end.
+  ;markupTable markupRows t
+)

Task/CSV-to-HTML-translation/J/csv-to-html-translation-2.j

@@ -0,0 +1,2 @@
+tag=: adverb def '[: (,&.>/)"1 m&(0&{::@[ , 1&{::@[ ,~ ]) L:0@]'
+makeHTMLtablefromCSV6=: 0&$: : ([: ; markupTable@markupRows@([ markupCells`(markupHdrCells@{. , markupCells@}.)@.[ fixcsv@encodeHTML))

Task/CSV-to-HTML-translation/J/csv-to-html-translation-3.j

@@ -0,0 +1,9 @@
+   CSVstrng=: noun define
+Character,Speech
+The multitude,The messiah! Show us the messiah!
+Brians mother,<angry>Now you listen here! He's not the messiah; he's a very naughty boy! Now go away!</angry>
+The multitude,Who are you?
+Brians mother,I'm his mother; that's who!
+The multitude,Behold his mother! Behold his mother!
+)
+   1 makeHTMLtablefromCSV CSVstrng

Task/CSV-to-HTML-translation/J/csv-to-html-translation-4.j

@@ -0,0 +1,8 @@
+<table>
+<tr><th>Character</th><th>Speech</th></tr>
+<tr><td>The multitude</td><td>The messiah! Show us the messiah!</td></tr>
+<tr><td>Brians mother</td><td>&lt;angry&gt;Now you listen here! He's not the messiah; he's a very naughty boy! Now go away!&lt;/angry&gt;</td></tr>
+<tr><td>The multitude</td><td>Who are you?</td></tr>
+<tr><td>Brians mother</td><td>I'm his mother; that's who!</td></tr>
+<tr><td>The multitude</td><td>Behold his mother! Behold his mother!</td></tr>
+</table>