Data commit

Task/Cumulative-standard-deviation/AppleScript/cumulative-standard-deviation-1.applescript

@@ -0,0 +1,53 @@
+-------------- CUMULATIVE STANDARD DEVIATION -------------
+
+-- stdDevInc :: Accumulator -> Num -> Index -> Accumulator
+-- stdDevInc :: {sum:, squaresSum:, stages:} -> Real -> Integer
+--                -> {sum:, squaresSum:, stages:}
+on stdDevInc(a, n, i)
+    set sum to (sum of a) + n
+    set squaresSum to (squaresSum of a) + (n ^ 2)
+    set stages to (stages of a) & ¬
+        ((squaresSum / i) - ((sum / i) ^ 2)) ^ 0.5
+
+    {sum:(sum of a) + n, squaresSum:squaresSum, stages:stages}
+end stdDevInc
+
+
+--------------------------- TEST -------------------------
+on run
+    set xs to [2, 4, 4, 4, 5, 5, 7, 9]
+
+    stages of foldl(stdDevInc, ¬
+        {sum:0, squaresSum:0, stages:[]}, xs)
+
+    --> {0.0, 1.0, 0.942809041582, 0.866025403784, 0.979795897113, 1.0, 1.399708424448, 2.0}
+end run
+
+
+
+-------------------- GENERIC FUNCTIONS -------------------
+
+-- foldl :: (a -> b -> a) -> a -> [b] -> a
+on foldl(f, startValue, xs)
+    tell mReturn(f)
+        set v to startValue
+        set lng to length of xs
+        repeat with i from 1 to lng
+            set v to |λ|(v, item i of xs, i, xs)
+        end repeat
+        return v
+    end tell
+end foldl
+
+
+-- mReturn :: First-class m => (a -> b) -> m (a -> b)
+on mReturn(f)
+    -- 2nd class handler function lifted into 1st class script wrapper.
+    if script is class of f then
+        f
+    else
+        script
+            property |λ| : f
+        end script
+    end if
+end mReturn

Task/Cumulative-standard-deviation/AppleScript/cumulative-standard-deviation-2.applescript

@@ -0,0 +1,2 @@
+{0.0, 1.0, 0.942809041582, 0.866025403784,
+0.979795897113, 1.0, 1.399708424448, 2.0}

Task/Cumulative-standard-deviation/AppleScript/cumulative-standard-deviation-3.applescript

@@ -0,0 +1,69 @@
+-------------- CUMULATIVE STANDARD DEVIATION -------------
+
+-- cumulativeStdDevns :: [Float] -> [Float]
+on cumulativeStdDevns(xs)
+    script go
+        on |λ|(sq, x, i)
+            set {s, q} to sq
+            set _s to x + s
+            set _q to q + (x ^ 2)
+
+            {{_s, _q}, ((_q / i) - ((_s / i) ^ 2)) ^ 0.5}
+        end |λ|
+    end script
+
+    item 2 of mapAccumL(go, {0, 0}, xs)
+end cumulativeStdDevns
+
+
+--------------------------- TEST -------------------------
+on run
+
+    cumulativeStdDevns({2, 4, 4, 4, 5, 5, 7, 9})
+
+end run
+
+
+------------------------- GENERIC ------------------------
+
+-- foldl :: (a -> b -> a) -> a -> [b] -> a
+on foldl(f, startValue, xs)
+    tell mReturn(f)
+        set v to startValue
+        set lng to length of xs
+        repeat with i from 1 to lng
+            set v to |λ|(v, item i of xs, i, xs)
+        end repeat
+        return v
+    end tell
+end foldl
+
+
+-- mapAccumL :: (acc -> x -> (acc, y)) -> acc -> [x] -> (acc, [y])
+on mapAccumL(f, acc, xs)
+    -- 'The mapAccumL function behaves like a combination of map and foldl;
+    -- it applies a function to each element of a list, passing an
+    -- accumulating parameter from |Left| to |Right|, and returning a final
+    -- value of this accumulator together with the new list.' (see Hoogle)
+    script
+        on |λ|(a, x, i)
+            tell mReturn(f) to set pair to |λ|(item 1 of a, x, i)
+            {item 1 of pair, (item 2 of a) & {item 2 of pair}}
+        end |λ|
+    end script
+
+    foldl(result, {acc, []}, xs)
+end mapAccumL
+
+
+-- mReturn :: First-class m => (a -> b) -> m (a -> b)
+on mReturn(f)
+    -- 2nd class handler function lifted into 1st class script wrapper.
+    if script is class of f then
+        f
+    else
+        script
+            property |λ| : f
+        end script
+    end if
+end mReturn