Data commit

Task/Euler-method/Ada/euler-method-1.ada

@@ -0,0 +1,11 @@
+generic
+   type Number is digits <>;
+package Euler is
+   type Waveform is array (Integer range <>) of Number;
+   function Solve
+            (  F      : not null access function (T, Y : Number) return Number;
+               Y0     : Number;
+               T0, T1 : Number;
+               N      : Positive
+            )  return Waveform;
+end Euler;

Task/Euler-method/Ada/euler-method-2.ada

@@ -0,0 +1,17 @@
+package body Euler is
+   function Solve
+            (  F      : not null access function (T, Y : Number) return Number;
+               Y0     : Number;
+               T0, T1 : Number;
+               N      : Positive
+            )  return Waveform is
+      dT : constant Number := (T1 - T0) / Number (N);
+   begin
+      return Y : Waveform (0..N) do
+         Y (0) := Y0;
+         for I in 1..Y'Last loop
+            Y (I) := Y (I - 1) + dT * F (T0 + dT * Number (I - 1), Y (I - 1));
+         end loop;
+      end return;
+   end Solve;
+end Euler;

Task/Euler-method/Ada/euler-method-3.ada

@@ -0,0 +1,18 @@
+with Ada.Text_IO;  use Ada.Text_IO;
+with Euler;
+
+procedure Test_Euler_Method is
+   package Float_Euler is new Euler (Float);
+   use Float_Euler;
+
+   function Newton_Cooling_Law (T, Y : Float) return Float is
+   begin
+      return -0.07 * (Y - 20.0);
+   end Newton_Cooling_Law;
+
+   Y : Waveform := Solve (Newton_Cooling_Law'Access, 100.0, 0.0, 100.0, 10);
+begin
+   for I in Y'Range loop
+      Put_Line (Integer'Image (10 * I) & ":" & Float'Image (Y (I)));
+   end loop;
+end Test_Euler_Method;