Data commit

Task/Fibonacci-sequence/SNOBOL4/fibonacci-sequence-1.sno

@@ -0,0 +1,8 @@
+	define("fib(a)")	:(fib_end)
+fib	fib = lt(a,2) a	:s(return)
+	fib = fib(a - 1) + fib(a - 2)	:(return)
+fib_end
+
+while	a = trim(input)	:f(end)
+	output = a " " fib(a)	:(while)
+end

Task/Fibonacci-sequence/SNOBOL4/fibonacci-sequence-2.sno

@@ -0,0 +1,4 @@
+        define('trfib(n,a,b)') :(trfib_end)
+trfib   trfib = eq(n,0) a :s(return)
+        trfib = trfib(n - 1, a + b, a) :(return)
+trfib_end

Task/Fibonacci-sequence/SNOBOL4/fibonacci-sequence-3.sno

@@ -0,0 +1,6 @@
+        define('ifib(n)f1,f2') :(ifib_end)
+ifib    ifib = le(n,2) 1 :s(return)
+        f1 = 1; f2 = 1
+if1     ifib = gt(n,2) f1 + f2 :f(return)
+        f1 = f2; f2 = ifib; n = n - 1 :(if1)
+ifib_end

Task/Fibonacci-sequence/SNOBOL4/fibonacci-sequence-4.sno

@@ -0,0 +1,5 @@
+        define('afib(n)s5') :(afib_end)
+afib    s5 = sqrt(5)
+        afib = (((1 + s5) / 2) ^ n - ((1 - s5) / 2) ^ n) / s5
+        afib = convert(afib,'integer') :(return)
+afib_end

Task/Fibonacci-sequence/SNOBOL4/fibonacci-sequence-5.sno

@@ -0,0 +1,5 @@
+loop    i = lt(i,10) i + 1 :f(show)
+        s1 = s1 fib(i) ' ' ; s2 = s2 trfib(i,0,1) ' '
+        s3 = s3 ifib(i) ' '; s4 = s4 afib(i) ' ' :(loop)
+show    output = s1; output = s2; output = s3; output = s4
+end