Data commit

Task/Generate-Chess960-starting-position/D/generate-chess960-starting-position-1.d

@@ -0,0 +1,13 @@
+void main() {
+    import std.stdio, std.range, std.algorithm, std.string, permutations2;
+
+    const pieces = "KQRrBbNN";
+    alias I = indexOf;
+    auto starts = pieces.dup.permutations.filter!(p =>
+            I(p, 'B') % 2 != I(p, 'b') % 2 && // Bishop constraint.
+            // King constraint.
+            ((I(p, 'r') < I(p, 'K') && I(p, 'K') < I(p, 'R')) ||
+             (I(p, 'R') < I(p, 'K') && I(p, 'K') < I(p, 'r'))))
+        .map!toUpper.array.sort().uniq;
+    writeln(starts.walkLength, "\n", starts.front);
+}

Task/Generate-Chess960-starting-position/D/generate-chess960-starting-position-2.d

@@ -0,0 +1,11 @@
+void main() {
+    import std.stdio, std.regex, std.range, std.algorithm, permutations2;
+
+    immutable pieces = "KQRRBBNN";
+    immutable bish = r"B(|..|....|......)B";
+    immutable king = r"R.*K.*R";
+    auto starts3 = permutations(pieces.dup)
+                   .filter!(p => p.match(bish) && p.match(king))
+                   .array.sort().uniq;
+    writeln(starts3.walkLength, "\n", starts3.front);
+}

Task/Generate-Chess960-starting-position/D/generate-chess960-starting-position-3.d

@@ -0,0 +1,13 @@
+void main() {
+    import std.stdio, std.random, std.array, std.range;
+
+    // Subsequent order unchanged by insertions.
+    auto start = "RKR".dup;
+    foreach (immutable piece; "QNN")
+        start.insertInPlace(uniform(0, start.length), piece);
+
+    immutable bishpos = uniform(0, start.length);
+    start.insertInPlace(bishpos, 'B');
+    start.insertInPlace(iota(bishpos % 2, start.length, 2)[uniform(0,$)], 'B');
+    start.writeln;
+}