Data commit

2023-07-01 11:58:00 -04:00 · 2023-07-01 11:58:00 -04:00 · cb5bb5e222
commit cb5bb5e222
parent 7387c8f97b
199093 changed files with 3378972 additions and 0 deletions
--- a/Task/ISBN13-check-digit/Excel/isbn13-check-digit-1.excel
+++ b/Task/ISBN13-check-digit/Excel/isbn13-check-digit-1.excel
@ -0,0 +1,26 @@
+ISBN13Check
+=LAMBDA(s,
+    LET(
+        ns, FILTERP(
+            LAMBDA(v,
+                NOT(ISERROR(v))
+            )
+        )(
+            VALUE(CHARSROW(s))
+        ),
+        ixs, SEQUENCE(
+            1, COLUMNS(ns),
+            1, 1
+        ),
+
+        0 = MOD(
+            SUM(
+                IF(0 <> MOD(ixs, 2),
+                    INDEX(ns, ixs),
+                    3 * INDEX(ns, ixs)
+                )
+            ),
+            10
+        )
+    )
+)
--- a/Task/ISBN13-check-digit/Excel/isbn13-check-digit-2.excel
+++ b/Task/ISBN13-check-digit/Excel/isbn13-check-digit-2.excel
@ -0,0 +1,25 @@
+CHARSROW
+=LAMBDA(s,
+    MID(s,
+        SEQUENCE(1, LEN(s), 1, 1),
+        1
+    )
+)
+
+
+FILTERP
+=LAMBDA(p,
+    LAMBDA(xs,
+        FILTER(xs, p(xs))
+    )
+)
+
+
+ISDIGIT
+=LAMBDA(c,
+    LET(
+        ic, CODE(c),
+
+        AND(47 < ic, 58 > ic)
+    )
+)