Data commit

Task/Inheritance-Single/E/inheritance-single-1.e

@@ -0,0 +1,18 @@
+def makeType(label, superstamps) {
+    def stamp {
+        to audit(audition) {
+            for s in superstamps { audition.ask(s) }
+            return true
+        }
+    }
+    def guard {
+        to coerce(specimen, ejector) {
+            if (__auditedBy(stamp, specimen)) {
+                return specimen
+            } else {
+                throw.eject(ejector, `$specimen is not a $label`)
+            }
+        }
+    }
+    return [guard, stamp]
+}

Task/Inheritance-Single/E/inheritance-single-2.e

@@ -0,0 +1,7 @@
+def [Animal, AnimalStamp] := makeType("Animal", [])
+
+def [Cat, CatStamp] := makeType("Cat", [AnimalStamp])
+def [Dog, DogStamp] := makeType("Dog", [AnimalStamp])
+
+def [Lab, LabStamp] := makeType("Lab", [DogStamp])
+def [Collie, CollieStamp] := makeType("Collie", [DogStamp])

Task/Inheritance-Single/E/inheritance-single-3.e

@@ -0,0 +1,3 @@
+def fido implements LabStamp {}
+def tom implements CatStamp {}
+def brick {} # not an animal

Task/Inheritance-Single/E/inheritance-single-4.e

@@ -0,0 +1,17 @@
+? fido :Animal
+# value: <fido>
+
+? fido :Cat
+# problem: <fido> is not a Cat
+
+? fido :Lab
+# value: <fido>
+
+? tom :Animal
+# value: <tom>
+
+? tom :Cat
+# value: <tom>
+
+? brick :Animal
+# problem: <brick> is not a Animal