Data commit

Task/Munchausen-numbers/AppleScript/munchausen-numbers-1.applescript

@@ -0,0 +1,80 @@
+------------------- MUNCHAUSEN NUMBER ? --------------------
+
+-- isMunchausen :: Int -> Bool
+on isMunchausen(n)
+
+    -- digitPowerSum :: Int -> Character -> Int
+    script digitPowerSum
+        on |λ|(a, c)
+            set d to c as integer
+            a + (d ^ d)
+        end |λ|
+    end script
+
+    (class of n is integer) and ¬
+        n = foldl(digitPowerSum, 0, characters of (n as string))
+
+end isMunchausen
+
+
+--------------------------- TEST ---------------------------
+on run
+
+    filter(isMunchausen, enumFromTo(1, 5000))
+
+    --> {1, 3435}
+
+end run
+
+
+-------------------- GENERIC FUNCTIONS ---------------------
+
+-- enumFromTo :: Int -> Int -> [Int]
+on enumFromTo(m, n)
+    if m ≤ n then
+        set lst to {}
+        repeat with i from m to n
+            set end of lst to i
+        end repeat
+        lst
+    else
+        {}
+    end if
+end enumFromTo
+
+-- filter :: (a -> Bool) -> [a] -> [a]
+on filter(p, xs)
+    tell mReturn(p)
+        set lst to {}
+        set lng to length of xs
+        repeat with i from 1 to lng
+            set v to item i of xs
+            if |λ|(v, i, xs) then set end of lst to v
+        end repeat
+        return lst
+    end tell
+end filter
+
+-- foldl :: (a -> b -> a) -> a -> [b] -> a
+on foldl(f, startValue, xs)
+    tell mReturn(f)
+        set v to startValue
+        set lng to length of xs
+        repeat with i from 1 to lng
+            set v to |λ|(v, item i of xs, i, xs)
+        end repeat
+        return v
+    end tell
+end foldl
+
+-- Lift 2nd class handler function into 1st class script wrapper
+-- mReturn :: Handler -> Script
+on mReturn(f)
+    if class of f is script then
+        f
+    else
+        script
+            property |λ| : f
+        end script
+    end if
+end mReturn

Task/Munchausen-numbers/AppleScript/munchausen-numbers-2.applescript

@@ -0,0 +1 @@
+{1, 3435}

Task/Munchausen-numbers/AppleScript/munchausen-numbers-3.applescript

@@ -0,0 +1,14 @@
+set MunchhausenNumbers to {}
+repeat with i from 1 to 5000
+    if (i > 0) then
+        set n to i
+        set s to 0
+        repeat until (n is 0)
+            tell n mod 10 to set s to s + it ^ it
+            set n to n div 10
+        end repeat
+        if (s = i) then set end of MunchhausenNumbers to i
+    end if
+end repeat
+
+return MunchhausenNumbers

Task/Munchausen-numbers/AppleScript/munchausen-numbers-4.applescript

@@ -0,0 +1 @@
+{1, 3435}