Data commit

2023-07-01 11:58:00 -04:00 · 2023-07-01 11:58:00 -04:00 · cb5bb5e222
commit cb5bb5e222
parent 7387c8f97b
199093 changed files with 3378972 additions and 0 deletions
--- a/Task/Permutations-Derangements/Quackery/permutations-derangements.quackery
+++ b/Task/Permutations-Derangements/Quackery/permutations-derangements.quackery
@ -0,0 +1,41 @@
+  [ stack ]                            is deranges.num (     --> [ )
+
+                               forward is (deranges)
+  [ over size
+    deranges.num share = iff
+      [ over temp take
+        swap nested join
+        temp put ]
+    else
+      [ dup size times
+         [ 2dup i^ pluck
+           dip [ over size ]
+           tuck != iff
+             [ rot swap
+               nested join
+               swap (deranges) ]
+           else
+             [ drop 2drop ] ] ]
+    2drop ]                      resolves (deranges)   ( [ [ -->   )
+
+  [ dup deranges.num put
+    [] swap times [ i^ join ]
+    [] temp put
+    [] swap (deranges)
+    temp take
+    deranges.num release ]             is derangements (   n --> [ )
+
+  [ dup 0 = iff [ drop 1 ] done
+    1 0 rot
+    1 - times
+      [ swap over + i^ 1+ * ]
+    nip ]                              is sub!         (   n --> n )
+
+  4 derangements witheach [ echo cr ]
+  cr
+  10 times
+    [ i^ echo sp
+      i^ derangements size echo sp
+      i^ sub! echo cr ]
+  cr
+  20 sub! echo