Data commit

Task/Pig-the-dice-game/MiniScript/pig-the-dice-game.mini

@@ -0,0 +1,44 @@
+// Pig the Dice for two players.
+Player = {}
+Player.score = 0
+Player.doTurn = function()
+    rolls = 0
+    pot = 0
+    print self.name + "'s Turn!"
+    while true
+        if self.score + pot >= goal then
+            print "   " + self.name.upper + " WINS WITH " + (self.score + pot) + "!"
+            inp = "H"
+        else
+            inp = input(self.name + ", you have " + pot + " in the pot.  [R]oll or Hold? ")
+        end if
+        if inp == "" or inp[0].upper == "R" then
+            die = ceil(rnd*6)
+            if die == 1 then
+                print "   You roll a 1.  Busted!"
+                return
+            else
+                print "   You roll a " + die + "."
+                pot = pot + die
+            end if
+        else
+            self.score = self.score + pot
+            return
+        end if
+    end while
+end function
+
+p1 = new Player
+p1.name = "Alice"
+p2 = new Player
+p2.name = "Bob"
+goal = 100
+
+while p1.score < goal and p2.score < goal
+    for player in [p1, p2]
+        print
+        print p1.name + ": " + p1.score + "  |  " + p2.name + ": " + p2.score
+        player.doTurn
+        if player.score >= goal then break
+    end for
+end while