aparler/RosettaCodeData
1
0
Fork 0
Code Issues 12 Pull requests 3 Projects Releases Packages Wiki Activity Actions

Data commit

Browse source
This commit is contained in:
Ingy döt Net 2023-07-01 11:58:00 -04:00
parent 7387c8f97b
commit cb5bb5e222
199093 changed files with 3378972 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

11
Task/Remove-duplicate-elements/REXX/remove-duplicate-elements-1.rexx Normal file
View file

@ -0,0 +1,11 @@
/*REXX program removes any duplicate elements (items) that are in a list (using a hash).*/
$= '2 3 5 7 11 13 17 19 cats 222 -100.2 +11 1.1 +7 7. 7 5 5 3 2 0 4.4 2' /*item list.*/
say 'original list:' $
say right( words($), 17, '─') 'words in the original list.'
z=; @.= /*initialize the NEW list & index list.*/
do j=1 for words($); y= word($, j) /*process the words (items) in the list*/
if @.y=='' then z= z y; @.y= . /*Not duplicated? Add to Z list,@ array*/
end /*j*/
say
say 'modified list:' space(z) /*stick a fork in it, we're all done. */
say right( words(z), 17, '─') 'words in the modified list.'

11
Task/Remove-duplicate-elements/REXX/remove-duplicate-elements-2.rexx Normal file
View file

@ -0,0 +1,11 @@
/*REXX program removes any duplicate elements (items) that are in a list (using a list).*/
$= '2 3 5 7 11 13 17 19 cats 222 -100.2 +11 1.1 +7 7. 7 5 5 3 2 0 4.4 2' /*item list.*/
say 'original list:' $
say right( words($), 17, '─') 'words in the original list.'
#= words($) /*process all the words in the list. */
do j=# by -1 for #; y= word($, j) /*get right-to-Left. */
_= wordpos(y, $, j + 1); if _\==0 then $= delword($, _, 1) /*Dup? Then delete it*/
end /*j*/
say
say 'modified list:' space($) /*stick a fork in it, we're all done. */
say right( words(z), 17, '─') 'words in the modified list.'

11
Task/Remove-duplicate-elements/REXX/remove-duplicate-elements-3.rexx Normal file
View file

@ -0,0 +1,11 @@
/*REXX program removes any duplicate elements (items) that are in a list (using 2 lists)*/
old = '2 3 5 7 11 13 17 19 cats 222 -100.2 +11 1.1 +7 7. 7 5 5 3 2 0 4.4 2'
say 'original list:' old
say right( words(old), 17, '─') 'words in the original list.'
new= /*start with a clean (list) slate. */
do j=1 for words(old); _= word(old, j) /*process the words in the OLD list. */
if wordpos(_, new)==0 then new= new _ /*Doesn't exist? Then add word to NEW.*/
end /*j*/
say
say 'modified list:' space(new) /*stick a fork in it, we're all done. */
say right( words(new), 17, '─') 'words in the modified list.'

28
Task/Remove-duplicate-elements/REXX/remove-duplicate-elements-4.rexx Normal file
View file

@ -0,0 +1,28 @@
/* REXX ************************************************************
* 26.11.2012 Walter Pachl
* added: show multiple occurrences
**********************************************************************/
old='2 3 5 7 11 13 17 19 cats 222 -100.2 +11 1.1 +7 7. 7 5 5',
'3 2 0 4.4 2'
say 'old list='old
say 'words in the old list=' words(old)
new=''
found.=0
count.=0
Do While old<>''
Parse Var old w old
If found.w=0 Then Do
new=new w
found.w=1
End
count.w=count.w+1
End
say 'new list='strip(new)
say 'words in the new list=' words(new)
Say 'Multiple occurrences:'
Say 'occ word'
Do While new<>''
Parse Var new w new
If count.w>1 Then
Say right(count.w,3) w
End