Data commit

Task/Roman-numerals-Encode/Mercury/roman-numerals-encode-1.mercury

@@ -0,0 +1,52 @@
+:- module roman.
+
+:- interface.
+
+:- import_module io.
+
+:- pred main(io::di, io::uo) is det.
+
+:- implementation.
+
+:- import_module char, int, list, string.
+
+main(!IO) :-
+    command_line_arguments(Args, !IO),
+    filter(is_all_digits, Args, CleanArgs),
+    foldl((pred(Arg::in, !.IO::di, !:IO::uo) is det :-
+               ( Roman = to_roman(Arg) ->
+                     format("%s => %s", [s(Arg), s(Roman)], !IO), nl(!IO)
+               ;     format("%s cannot be converted.", [s(Arg)], !IO), nl(!IO) )
+          ), CleanArgs, !IO).
+
+:- func to_roman(string::in) = (string::out) is semidet.
+to_roman(Number) = from_char_list(build_roman(reverse(to_char_list(Number)))).
+
+:- func build_roman(list(char)) = list(char).
+:- mode build_roman(in)         = out is semidet.
+build_roman([]) = [].
+build_roman([D|R]) = Roman :-
+    map(promote, build_roman(R), Interim),
+    Roman = Interim ++ digit_to_roman(D).
+
+:- func digit_to_roman(char) = list(char).
+:- mode digit_to_roman(in)   = out is semidet.
+digit_to_roman('0') = [].
+digit_to_roman('1') = ['I'].
+digit_to_roman('2') = ['I','I'].
+digit_to_roman('3') = ['I','I','I'].
+digit_to_roman('4') = ['I','V'].
+digit_to_roman('5') = ['V'].
+digit_to_roman('6') = ['V','I'].
+digit_to_roman('7') = ['V','I','I'].
+digit_to_roman('8') = ['V','I','I','I'].
+digit_to_roman('9') = ['I','X'].
+
+:- pred promote(char::in, char::out) is semidet.
+promote('I', 'X').
+promote('V', 'L').
+promote('X', 'C').
+promote('L', 'D').
+promote('C', 'M').
+
+:- end_module roman.

Task/Roman-numerals-Encode/Mercury/roman-numerals-encode-2.mercury

@@ -0,0 +1,48 @@
+:- module roman2.
+
+:- interface.
+
+:- import_module io.
+
+:- pred main(io::di, io::uo) is det.
+
+:- implementation.
+
+:- import_module char, int, list, string.
+
+main(!IO) :-
+    command_line_arguments(Args, !IO),
+    filter_map(to_int, Args, CleanArgs),
+    foldl((pred(Arg::in, !.IO::di, !:IO::uo) is det :-
+               ( Roman = to_roman(Arg) ->
+                     format("%i => %s",
+                            [i(Arg), s(from_char_list(Roman))], !IO),
+                     nl(!IO)
+               ;     format("%i cannot be converted.", [i(Arg)], !IO), nl(!IO) )
+          ), CleanArgs, !IO).
+
+:- func to_roman(int) = list(char).
+:- mode to_roman(in)  = out is semidet.
+to_roman(N) = ( N >= 1000 ->
+                    ['M'] ++ to_roman(N - 1000)
+              ;( N >= 100 ->
+                     digit(N / 100, 'C', 'D', 'M') ++ to_roman(N rem 100)
+               ;( N >= 10 ->
+                      digit(N / 10, 'X', 'L', 'C') ++ to_roman(N rem 10)
+                ;( N >= 1 ->
+                       digit(N, 'I', 'V', 'X')
+                 ; [] ) ) ) ).
+
+:- func digit(int, char, char, char) = list(char).
+:- mode digit(in,  in,   in,   in)   = out is semidet.
+digit(1, X, _, _) = [X].
+digit(2, X, _, _) = [X, X].
+digit(3, X, _, _) = [X, X, X].
+digit(4, X, Y, _) = [X, Y].
+digit(5, _, Y, _) = [Y].
+digit(6, X, Y, _) = [Y, X].
+digit(7, X, Y, _) = [Y, X, X].
+digit(8, X, Y, _) = [Y, X, X, X].
+digit(9, X, _, Z) = [X, Z].
+
+:- end_module roman2.