Data commit

Task/Sorting-algorithms-Shell-sort/Action-/sorting-algorithms-shell-sort.action

@@ -0,0 +1,64 @@
+PROC PrintArray(INT ARRAY a INT size)
+  INT i
+
+  Put('[)
+  FOR i=0 TO size-1
+  DO
+    IF i>0 THEN Put(' ) FI
+    PrintI(a(i))
+  OD
+  Put(']) PutE()
+RETURN
+
+PROC ShellSort(INT ARRAY a INT size)
+  INT stp,i,j,tmp,v
+
+  stp=size/2
+  WHILE stp>0
+  DO
+    FOR i=stp TO size-1
+    DO
+      tmp=a(i)
+      j=i
+
+      WHILE j>=stp
+      DO
+        v=a(j-stp)
+        IF v<=tmp THEN EXIT FI
+
+        a(j-stp)=a(j)
+        a(j)=v
+        j==-stp
+      OD
+
+      a(j)=tmp
+    OD
+
+    stp=stp/2
+  OD
+RETURN
+
+PROC Test(INT ARRAY a INT size)
+  PrintE("Array before sort:")
+  PrintArray(a,size)
+  ShellSort(a,size)
+  PrintE("Array after sort:")
+  PrintArray(a,size)
+  PutE()
+RETURN
+
+PROC Main()
+  INT ARRAY
+    a(10)=[1 4 65535 0 3 7 4 8 20 65530],
+    b(21)=[10 9 8 7 6 5 4 3 2 1 0
+      65535 65534 65533 65532 65531
+      65530 65529 65528 65527 65526],
+    c(8)=[101 102 103 104 105 106 107 108],
+    d(12)=[1 65535 1 65535 1 65535 1
+      65535 1 65535 1 65535]
+
+  Test(a,10)
+  Test(b,21)
+  Test(c,8)
+  Test(d,12)
+RETURN