Data commit

Task/Sorting-algorithms-Shell-sort/NetRexx/sorting-algorithms-shell-sort.netrexx

@@ -0,0 +1,45 @@
+/* NetRexx */
+options replace format comments java crossref savelog symbols binary
+
+placesList = [String -
+    "UK  London",     "US  New York",   "US  Boston",     "US  Washington" -
+  , "UK  Washington", "US  Birmingham", "UK  Birmingham", "UK  Boston"     -
+]
+sortedList = shellSort(String[] Arrays.copyOf(placesList, placesList.length))
+
+lists = [placesList, sortedList]
+loop ln = 0 to lists.length - 1
+  cl = lists[ln]
+  loop ct = 0 to cl.length - 1
+    say cl[ct]
+    end ct
+    say
+  end ln
+
+return
+
+method shellSort(a = String[]) public constant binary returns String[]
+
+  n = a.length
+  inc = int Math.round(double n / 2.0)
+  loop label inc while inc > 0
+    loop i_ = inc to n - 1
+      temp = a[i_]
+      j_ = i_
+      loop label j_ while j_ >= inc
+        if \(a[j_ - inc].compareTo(temp) > 0) then leave j_
+        a[j_] = a[j_ - inc]
+        j_ = j_ - inc
+        end j_
+      a[j_] = temp
+      end i_
+    inc = int Math.round(double inc / 2.2)
+    end inc
+
+  return a
+
+method isTrue public constant binary returns boolean
+  return 1 == 1
+
+method isFalse public constant binary returns boolean
+  return \isTrue