Data update

2026-04-30 12:34:36 -04:00 · 2026-04-30 12:34:36 -04:00 · cbaf4c4b64
commit cbaf4c4b64
parent 4bb20c9b71
12390 changed files with 318560 additions and 27248 deletions
--- a/Task/ADFGVX-cipher/APL/adfgvx-cipher.apl
+++ b/Task/ADFGVX-cipher/APL/adfgvx-cipher.apl
@ -0,0 +1,39 @@
+adfgvx←{
+    n←⎕NS''
+    n.split←↑{⍺≥⍴⍵:⊂⍵ ⋄ (⊂⍺↑⍵),⍺∇⍺↓⍵}
+
+    n.enc←⍺{
+        t←∊(∘.,⍨'ADFGVX')[⊃∘⍸∘(⍺⍺∘=)¨⍵]
+        w←↓⍉((⍴⍵⍵)split t)[;⍋⍵⍵]
+        1↓∊' ',¨w~¨' '
+    }⍵
+
+    n.dec←⍺{
+        t←↓2 split (∊(⍉↑⍵⊆⍨' '≠⍵)[;⍋⍋⍵⍵])~' '
+        ⍺⍺['ADFGVX'∘⍳¨t]
+    }⍵
+
+    n
+}
+
+adfgvx_test←{
+    square←6 6⍴(⎕A,⎕D)[?⍨36]
+    ⎕←'Polybius square:'
+    ⎕←' ─ADFGVX','│┼││││││','A D F G V X' ⍪'─'⍪(11⍴1 0)\square
+    ⎕←''
+
+    key←{
+        file←'e:\unixdict.txt'
+        dict←(~data∊⎕TC)⊆data←⊃⎕NGET file
+        dict←(⍵{⍺=≢⍵}¨dict)/dict
+        dict←({⍵≡∪⍵}¨dict)/dict
+        1⎕C ⊃dict[?⍴dict]
+    }9
+    ⎕←'Key: ',key
+
+    a←square adfgvx key
+
+    ⎕←'Plaintext: ',plaintext←'ATTACKAT1200AM'
+    ⎕←'Encrypted: ',encrypted←a.enc plaintext
+    ⎕←'Decrypted: ',a.dec encrypted
+}