Data update

Task/Vector/Lang/vector-1.lang

@@ -0,0 +1,40 @@
+struct &Vector {
+	$x
+	$y
+}
+
+fp.initVector = ($x, $y) -> {
+	return &Vector(fn.double($x), fn.double($y))
+}
+
+fp.addVector = ($a, $b) -> {
+	return parser.op(&Vector($a::$x + $b::$x, $a::$y + $b::$y))
+}
+
+fp.subVector = ($a, $b) -> {
+	return parser.op(&Vector($a::$x - $b::$x, $a::$y - $b::$y))
+}
+
+fp.mulVector = ($vec, $scalar) -> {
+	return parser.op(&Vector($vec::$x * $scalar, $vec::$y * $scalar))
+}
+
+fp.divVector = ($vec, $scalar) -> {
+	return parser.op(&Vector($vec::$x / $scalar, $vec::$y / $scalar))
+}
+
+fp.printVector = ($vec) -> {
+	fn.println([parser.op($vec::$x), parser.op($vec::$y)])
+}
+
+$vec1 = fp.initVector(5, 7)
+$vec2 = fp.initVector(2, 3)
+
+fp.printVector($vec1)
+fp.printVector($vec2)
+fn.println()
+
+fp.printVector(fp.addVector($vec1, $vec2))
+fp.printVector(fp.subVector($vec1, $vec2))
+fp.printVector(fp.mulVector($vec1, 11))
+fp.printVector(fp.divVector($vec1, 2))

Task/Vector/Lang/vector-2.lang

@@ -0,0 +1,41 @@
+class &Vector {
+	+$x
+	+$y
+
+	+construct = ($x{number}, $y{number}) -> {
+		::$x $= double($x)
+		::$y $= double($y)
+	}
+
+	+op:add = ($op{OBJECT}) -> {
+		return parser.op(&Vector(::$x + $op::$x, ::$y + $op::$y))
+	}
+
+	+op:sub = ($op{OBJECT}) -> {
+		return parser.op(&Vector(::$x - $op::$x, ::$y - $op::$y))
+	}
+
+	+op:mul = ($op{number}) -> {
+		return parser.op(&Vector(::$x * $op, ::$y * $op))
+	}
+
+	+op:div = ($op{number}) -> {
+		return parser.op(&Vector(::$x / $op, ::$y / $op))
+	}
+
+	+to:text = () -> {
+		return [parser.op(::$x), parser.op(::$y)]
+	}
+}
+
+$vec1 = &Vector(5, 7)
+$vec2 = &Vector(2, 3)
+
+fn.println($vec1)
+fn.println($vec2)
+fn.println()
+
+fn.println(parser.op($vec1 + $vec2))
+fn.println(parser.op($vec1 - $vec2))
+fn.println(parser.op($vec1 * 11))
+fn.println(parser.op($vec1 / 2))