A-M baby

Task/Four-bit-adder/D/four-bit-adder.d

@@ -0,0 +1,67 @@
+import std.stdio, std.traits;
+
+void fourBitsAdder(T)(in T a0, in T a1, in T a2, in T a3,
+                      in T b0, in T b1, in T b2, in T b3,
+                      out T o0, out T o1,
+                      out T o2, out T o3,
+                      out T overflow) pure nothrow {
+
+    // A XOR using only NOT, AND and OR, as task requires
+    static T xor(in T x, in T y) pure nothrow {
+        return (~x & y) | (x & ~y);
+    }
+
+    static void halfAdder(in T a, in T b,
+                          out T s, out T c) pure nothrow {
+        s = xor(a, b);
+        // s = a ^ b; // a natural XOR in D
+        c = a & b;
+    }
+
+    static void fullAdder(in T a, in T b, in T ic,
+                          out T s, out T oc) pure nothrow {
+        T ps, pc, tc;
+
+        halfAdder(/*input*/a, b,   /*output*/ps, pc);
+        halfAdder(/*input*/ps, ic, /*output*/s, tc);
+        oc = tc | pc;
+    }
+
+    T zero, tc0, tc1, tc2;
+
+    fullAdder(/*input*/a0, b0, zero, /*output*/o0, tc0);
+    fullAdder(/*input*/a1, b1, tc0,  /*output*/o1, tc1);
+    fullAdder(/*input*/a2, b2, tc1,  /*output*/o2, tc2);
+    fullAdder(/*input*/a3, b3, tc2,  /*output*/o3, overflow);
+}
+
+void main() {
+    alias size_t T;
+    static assert(isUnsigned!T);
+
+    enum T one = T.max,
+           zero = T.min,
+           a0 = zero, a1 = one, a2 = zero, a3 = zero,
+           b0 = zero, b1 = one, b2 = one,  b3 = one;
+    T s0, s1, s2, s3, overflow;
+
+    fourBitsAdder(/*input*/ a0, a1, a2, a3,
+                  /*input*/ b0, b1, b2, b3,
+                  /*output*/s0, s1, s2, s3, overflow);
+
+    writefln("      a3 %032b", a3);
+    writefln("      a2 %032b", a2);
+    writefln("      a1 %032b", a1);
+    writefln("      a0 %032b", a0);
+    writefln("      +");
+    writefln("      b3 %032b", b3);
+    writefln("      b2 %032b", b2);
+    writefln("      b1 %032b", b1);
+    writefln("      b0 %032b", b0);
+    writefln("      =");
+    writefln("      s3 %032b", s3);
+    writefln("      s2 %032b", s2);
+    writefln("      s1 %032b", s1);
+    writefln("      s0 %032b", s0);
+    writefln("overflow %032b", overflow);
+}