2016 Update

Task/Factorial/AppleScript/factorial-3.applescript

@@ -0,0 +1,63 @@
+-- factorial :: Int -> Int
+on factorial(x)
+    script product
+        on lambda(a, b)
+            a * b
+        end lambda
+    end script
+
+    foldl(product, 1, range(1, x))
+end factorial
+
+
+
+-- TEST
+on run
+
+    factorial(11)
+
+    --> 39916800
+
+end run
+
+
+-- GENERIC LIBRARY PRIMITIVES
+
+-- foldl :: (a -> b -> a) -> a -> [b] -> a
+on foldl(f, startValue, xs)
+    tell mReturn(f)
+        set v to startValue
+        set lng to length of xs
+        repeat with i from 1 to lng
+            set v to lambda(v, item i of xs, i, xs)
+        end repeat
+        return v
+    end tell
+end foldl
+
+-- range :: Int -> Int -> [Int]
+on range(m, n)
+    if n < m then
+        set d to -1
+    else
+        set d to 1
+    end if
+    set lst to {}
+    repeat with i from m to n by d
+        set end of lst to i
+    end repeat
+    return lst
+end range
+
+
+-- Lift 2nd class handler function into 1st class script wrapper
+-- mReturn :: Handler -> Script
+on mReturn(f)
+    if class of f is script then
+        f
+    else
+        script
+            property lambda : f
+        end script
+    end if
+end mReturn