Initial data commit

Task/Cantor-set/Excel/cantor-set-1.excel

@@ -0,0 +1,90 @@
+CANTOR
+=LAMBDA(n,
+    APPLYN(n)(
+        LAMBDA(grid,
+            APPENDROWS(grid)(
+                CANTOROW(
+                    LASTROW(grid)
+                )
+            )
+        )
+    )({0,1})
+)
+
+
+CANTOROW
+=LAMBDA(xys,
+    LET(
+        nCols, COLUMNS(xys),
+
+        IF(2 > nCols,
+            xys,
+            IF(3 < nCols,
+                APPENDCOLS(
+                    CANTORSLICES(TAKECOLS(2)(xys))
+                )(
+                    CANTOROW(DROPCOLS(2)(xys))
+                ),
+                CANTORSLICES(TAKECOLS(2)(xys))
+            )
+        )
+    )
+)
+
+
+CANTORSLICES
+=LAMBDA(ab,
+    LET(
+        a, INDEX(ab, 1),
+        b, INDEX(ab, 2),
+        third, (b - a) / 3,
+
+        CHOOSE({1,2,3,4}, a, a + third, b - third, b)
+    )
+)
+
+
+SHOWCANTOR
+=LAMBDA(grid,
+    LET(
+        leaves, LASTROW(grid),
+        leafWidth, INDEX(leaves, 1, 2) - INDEX(leaves, 1, 1),
+        leafCount, 1 / leafWidth,
+
+        SHOWCANTROWS(leafCount)(grid)
+    )
+)
+
+
+SHOWCANTROWS
+=LAMBDA(leafCount,
+    LAMBDA(grid,
+        LET(
+            xs, FILTERP(
+               LAMBDA(x, NOT(ISNA(x)))
+            )(
+                HEADCOL(grid)
+            ),
+
+            runLengths, LAMBDA(x,
+                CEILING.MATH(leafCount * x))(
+                    SUBTRACT(TAILROW(xs))(INITROW(xs)
+                )
+            ),
+
+            iCols, SEQUENCE(1, COLUMNS(runLengths)),
+
+            CONCAT(
+                REPT(
+                    IF(ISEVEN(iCols), " ", "█"),
+                    runLengths
+                )
+            ) & IF(1 < ROWS(grid),
+                CHAR(10) & SHOWCANTROWS(leafCount)(
+                    TAILCOL(grid)
+                ),
+                ""
+            )
+        )
+    )
+)

Task/Cantor-set/Excel/cantor-set-2.excel

@@ -0,0 +1,157 @@
+APPENDCOLS
+=LAMBDA(xs,
+    LAMBDA(ys,
+        LET(
+            nx, COLUMNS(xs),
+            ny, COLUMNS(ys),
+            colIndexes, SEQUENCE(1, nx + ny),
+            rowIndexes, SEQUENCE(MAX(ROWS(xs), ROWS(ys))),
+
+            IFERROR(
+                IF(nx < colIndexes,
+                    INDEX(ys, rowIndexes, colIndexes - nx),
+                    INDEX(xs, rowIndexes, colIndexes)
+                ),
+                NA()
+            )
+        )
+    )
+)
+
+
+APPENDROWS
+=LAMBDA(xs,
+    LAMBDA(ys,
+        LET(
+            nx, ROWS(xs),
+            rowIndexes, SEQUENCE(nx + ROWS(ys)),
+            colIndexes, SEQUENCE(
+                1,
+                MAX(COLUMNS(xs), COLUMNS(ys))
+            ),
+
+            IFERROR(
+                IF(rowIndexes <= nx,
+                    INDEX(xs, rowIndexes, colIndexes),
+                    INDEX(ys, rowIndexes - nx, colIndexes)
+                ),
+                NA()
+            )
+        )
+    )
+)
+
+
+APPLYN
+=LAMBDA(n,
+    LAMBDA(f,
+        LAMBDA(x,
+            IF(0 < n,
+                APPLYN(n - 1)(f)(
+                    f(x)
+                ),
+                x
+            )
+        )
+    )
+)
+
+
+DROPCOLS
+=LAMBDA(n,
+    LAMBDA(xs,
+        INDEX(
+            xs,
+            SEQUENCE(ROWS(xs), 1),
+            SEQUENCE(1, (COLUMNS(xs) - n), 1 + n, 1)
+        )
+    )
+)
+
+
+FILTERP
+=LAMBDA(p,
+    LAMBDA(xs,
+        FILTER(xs, p(xs))
+    )
+)
+
+
+HEADCOL
+=LAMBDA(xs,
+    LET(REM, "The first item of each column in xs",
+
+        INDEX(xs, 1, SEQUENCE(1, COLUMNS(xs)))
+    )
+)
+
+
+INITROW
+=LAMBDA(xs,
+    INDEX(
+        xs,
+        SEQUENCE(
+            1,
+            COLUMNS(xs) - 1,
+            1, 1
+        )
+    )
+)
+
+
+LASTROW
+=LAMBDA(xs,
+    INDEX(
+        xs,
+        ROWS(xs),
+        SEQUENCE(1, COLUMNS(xs), 1, 1)
+    )
+)
+
+
+SUBTRACT
+=LAMBDA(a,
+    LAMBDA(b, a - b)
+)
+
+
+TAILCOL
+=LAMBDA(cols,
+    LET(REM, "The tail of each column in the grid.",
+
+        INDEX(
+            cols,
+            SEQUENCE(ROWS(cols) - 1, 1, 2, 1),
+            SEQUENCE(1, COLUMNS(cols))
+        )
+    )
+)
+
+
+TAILROW
+=LAMBDA(xs,
+    LET(REM,"The tail of each row in the grid",
+        n, COLUMNS(xs) - 1,
+
+        IF(0 < n,
+            INDEX(
+                xs,
+                SEQUENCE(ROWS(xs), 1, 1, 1),
+                SEQUENCE(1, n, 2, 1)
+            ),
+            NA()
+        )
+    )
+)
+
+
+TAKECOLS
+=LAMBDA(n,
+    LAMBDA(xs,
+        INDEX(
+            xs,
+            SEQUENCE(ROWS(xs)),
+            SEQUENCE(1, n)
+        )
+    )
+)

Task/Cantor-set/Excel/cantor-set-3.excel

@@ -0,0 +1 @@
+█

Task/Cantor-set/Excel/cantor-set-4.excel

@@ -0,0 +1,2 @@
+███
+█ █

Task/Cantor-set/Excel/cantor-set-5.excel

@@ -0,0 +1,3 @@
+█████████
+███   ███
+█ █   █ █

Task/Cantor-set/Excel/cantor-set-6.excel

@@ -0,0 +1,4 @@
+███████████████████████████
+█████████         █████████
+███   ███         ███   ███
+█ █   █ █         █ █   █ █