Initial data commit

Task/Closures-Value-capture/AppleScript/closures-value-capture-1.applescript

@@ -0,0 +1,17 @@
+on run
+    set fns to {}
+
+    repeat with i from 1 to 10
+        set end of fns to closure(i)
+    end repeat
+
+    |λ|() of item 3 of fns
+end run
+
+on closure(x)
+    script
+        on |λ|()
+            x * x
+        end |λ|
+    end script
+end closure

Task/Closures-Value-capture/AppleScript/closures-value-capture-2.applescript

@@ -0,0 +1,54 @@
+-- CLOSURE --------------------------------------------------------------------
+
+script closure
+    on |λ|(x)
+        script
+            on |λ|()
+                x * x
+            end |λ|
+        end script
+    end |λ|
+end script
+
+|λ|() of (item 3 of (map(closure, enumFromTo(1, 10))))
+
+
+-- GENERIC FUNCTIONS ----------------------------------------------------------
+
+-- enumFromTo :: Int -> Int -> [Int]
+on enumFromTo(m, n)
+    if n < m then
+        set d to -1
+    else
+        set d to 1
+    end if
+    set lst to {}
+    repeat with i from m to n by d
+        set end of lst to i
+    end repeat
+    return lst
+end enumFromTo
+
+-- map :: (a -> b) -> [a] -> [b]
+on map(f, xs)
+    tell mReturn(f)
+        set lng to length of xs
+        set lst to {}
+        repeat with i from 1 to lng
+            set end of lst to |λ|(item i of xs, i, xs)
+        end repeat
+        return lst
+    end tell
+end map
+
+-- Lift 2nd class handler function into 1st class script wrapper
+-- mReturn :: Handler -> Script
+on mReturn(f)
+    if class of f is script then
+        f
+    else
+        script
+            property |λ| : f
+        end script
+    end if
+end mReturn