Initial data commit

Task/Factorial/AppleScript/factorial-1.applescript

@@ -0,0 +1,8 @@
+on factorial(x)
+    if x < 0 then return 0
+    set R to 1
+    repeat while x > 1
+        set {R, x} to {R * x, x - 1}
+    end repeat
+    return R
+end factorial

Task/Factorial/AppleScript/factorial-2.applescript

@@ -0,0 +1,8 @@
+-- factorial :: Int -> Int
+on factorial(x)
+    if x > 1 then
+        x * (factorial(x - 1))
+    else
+        1
+    end if
+end factorial

Task/Factorial/AppleScript/factorial-3.applescript

@@ -0,0 +1,72 @@
+------------------------ FACTORIAL -----------------------
+
+-- factorial :: Int -> Int
+on factorial(x)
+
+    product(enumFromTo(1, x))
+
+end factorial
+
+
+--------------------------- TEST -------------------------
+on run
+
+    factorial(11)
+
+    --> 39916800
+
+end run
+
+
+-------------------- GENERIC FUNCTIONS -------------------
+
+-- enumFromTo :: Int -> Int -> [Int]
+on enumFromTo(m, n)
+    if m ≤ n then
+        set xs to {}
+        repeat with i from m to n
+            set end of xs to i
+        end repeat
+        xs
+    else
+        {}
+    end if
+end enumFromTo
+
+
+-- foldl :: (a -> b -> a) -> a -> [b] -> a
+on foldl(f, startValue, xs)
+    tell mReturn(f)
+        set v to startValue
+        set lng to length of xs
+        repeat with i from 1 to lng
+            set v to |λ|(v, item i of xs, i, xs)
+        end repeat
+        return v
+    end tell
+end foldl
+
+
+-- Lift 2nd class handler function into 1st class script wrapper
+-- mReturn :: Handler -> Script
+on mReturn(f)
+    if class of f is script then
+        f
+    else
+        script
+            property |λ| : f
+        end script
+    end if
+end mReturn
+
+
+-- product :: [Num] -> Num
+on product(xs)
+    script multiply
+        on |λ|(a, b)
+            a * b
+        end |λ|
+    end script
+
+    foldl(multiply, 1, xs)
+end product