Initial data commit

2023-07-01 11:58:00 -04:00 · 2023-07-01 11:58:00 -04:00 · f23f22d71c
commit f23f22d71c
parent 72d218235f
199087 changed files with 3378941 additions and 0 deletions
--- a/Task/Fibonacci-sequence/Excel/fibonacci-sequence-2.excel
+++ b/Task/Fibonacci-sequence/Excel/fibonacci-sequence-2.excel
@ -0,0 +1,57 @@
+APPENDROWS
+=LAMBDA(xs,
+    LAMBDA(ys,
+        LET(
+            nx, ROWS(xs),
+            rowIndexes, SEQUENCE(nx + ROWS(ys)),
+            colIndexes, SEQUENCE(
+                1,
+                MAX(COLUMNS(xs), COLUMNS(ys))
+            ),
+
+            IFERROR(
+                IF(rowIndexes <= nx,
+                    INDEX(xs, rowIndexes, colIndexes),
+                    INDEX(ys, rowIndexes - nx, colIndexes)
+                ),
+                NA()
+            )
+        )
+    )
+)
+
+
+APPLYN
+=LAMBDA(n,
+    LAMBDA(f,
+        LAMBDA(x,
+            IF(0 < n,
+                APPLYN(n - 1)(f)(
+                    f(x)
+                ),
+                x
+            )
+        )
+    )
+)
+
+LASTNROWS
+=LAMBDA(n,
+    LAMBDA(xs,
+        LET(
+            nRows, COUNTA(xs),
+            x, MIN(nRows, n),
+
+            IF(0 < n,
+                INDEX(
+                    xs,
+                    SEQUENCE(
+                        x, 1,
+                        1 + nRows - x,  1
+                    )
+                ),
+                NA()
+            )
+        )
+    )
+)