Initial data commit

Task/JSON/Tcl/json-1.tcl

@@ -0,0 +1,5 @@
+package require json
+set sample {{ "foo": 1, "bar": [10, "apples"] }}
+
+set parsed [json::json2dict $sample]
+puts $parsed

Task/JSON/Tcl/json-2.tcl

@@ -0,0 +1,42 @@
+package require Tcl 8.6
+package require json::write
+
+proc tcl2json value {
+    # Guess the type of the value; deep *UNSUPPORTED* magic!
+    regexp {^value is a (.*?) with a refcount} \
+	[::tcl::unsupported::representation $value] -> type
+
+    switch $type {
+	string {
+	    return [json::write string $value]
+	}
+	dict {
+	    return [json::write object {*}[
+		dict map {k v} $value {tcl2json $v}]]
+	}
+	list {
+	    return [json::write array {*}[lmap v $value {tcl2json $v}]]
+	}
+	int - double {
+	    return [expr {$value}]
+	}
+	booleanString {
+	    return [expr {$value ? "true" : "false"}]
+	}
+	default {
+	    # Some other type; do some guessing...
+	    if {$value eq "null"} {
+		# Tcl has *no* null value at all; empty strings are semantically
+		# different and absent variables aren't values. So cheat!
+		return $value
+	    } elseif {[string is integer -strict $value]} {
+		return [expr {$value}]
+	    } elseif {[string is double -strict $value]} {
+		return [expr {$value}]
+	    } elseif {[string is boolean -strict $value]} {
+		return [expr {$value ? "true" : "false"}]
+	    }
+	    return [json::write string $value]
+	}
+    }
+}

Task/JSON/Tcl/json-3.tcl

@@ -0,0 +1,2 @@
+set d [dict create blue [list 1 2] ocean water]
+puts [tcl2json $d]