Initial data commit

Task/Matrix-transposition/AppleScript/matrix-transposition-1.applescript

@@ -0,0 +1,21 @@
+on run
+    transpose([[1, 2, 3], [4, 5, 6], [7, 8, 9], [10, 11, 12]])
+
+    --> {{1, 4, 7, 10}, {2, 5, 8, 11}, {3, 6, 9, 12}}
+end run
+
+on transpose(xss)
+    set lstTrans to {}
+
+    repeat with iCol from 1 to length of item 1 of xss
+        set lstCol to {}
+
+        repeat with iRow from 1 to length of xss
+            set end of lstCol to item iCol of item iRow of xss
+        end repeat
+
+        set end of lstTrans to lstCol
+    end repeat
+
+    return lstTrans
+end transpose

Task/Matrix-transposition/AppleScript/matrix-transposition-2.applescript

@@ -0,0 +1,53 @@
+------------------------ TRANSPOSE -----------------------
+
+-- transpose :: [[a]] -> [[a]]
+on transpose(xss)
+    script column
+        on |λ|(_, iCol)
+            script row
+                on |λ|(xs)
+                    item iCol of xs
+                end |λ|
+            end script
+
+            map(row, xss)
+        end |λ|
+    end script
+
+    map(column, item 1 of xss)
+end transpose
+
+
+--------------------------- TEST -------------------------
+on run
+    transpose([[1, 2, 3], [4, 5, 6], [7, 8, 9], [10, 11, 12]])
+
+    --> {{1, 4, 7, 10}, {2, 5, 8, 11}, {3, 6, 9, 12}}
+end run
+
+
+-------------------- GENERIC FUNCTIONS -------------------
+
+-- map :: (a -> b) -> [a] -> [b]
+on map(f, xs)
+    tell mReturn(f)
+        set lng to length of xs
+        set lst to {}
+        repeat with i from 1 to lng
+            set end of lst to |λ|(item i of xs, i, xs)
+        end repeat
+        return lst
+    end tell
+end map
+
+-- Lift 2nd class handler function into 1st class script wrapper
+-- mReturn :: Handler -> Script
+on mReturn(f)
+    if class of f is script then
+        f
+    else
+        script
+            property |λ| : f
+        end script
+    end if
+end mReturn

Task/Matrix-transposition/AppleScript/matrix-transposition-3.applescript

@@ -0,0 +1 @@
+{{1, 4, 7, 10}, {2, 5, 8, 11}, {3, 6, 9, 12}}