Initial data commit

Task/Rep-string/Excel/rep-string-1.excel

@@ -0,0 +1,37 @@
+REPCYCLES
+=LAMBDA(s,
+    LET(
+        n, LEN(s),
+        xs, FILTERP(
+            LAMBDA(pfx,
+                s = TAKECYCLESTRING(n)(pfx)
+            )
+        )(
+            TAILCOLS(
+                INITS(
+                   MID(s, 1, QUOTIENT(n, 2))
+                )
+            )
+        ),
+
+        IF(ISERROR(xs), NA(), xs)
+    )
+)
+
+
+TAKECYCLESTRING
+=LAMBDA(n,
+    LAMBDA(s,
+        LET(
+            lng, LEN(s),
+
+            MID(
+                IF(n < lng,
+                    s,
+                    REPT(s, CEILING.MATH(n / lng))
+                ),
+                1, n
+            )
+        )
+    )
+)

Task/Rep-string/Excel/rep-string-2.excel

@@ -0,0 +1,40 @@
+FILTERP
+=LAMBDA(p,
+    LAMBDA(xs,
+        FILTER(xs, p(xs))
+    )
+)
+
+
+INITS
+=LAMBDA(s,
+    MID(
+        s,
+        1, SEQUENCE(
+            1, 1 + LEN(s),
+            0, 1
+        )
+    )
+)
+
+
+LASTCOL
+=LAMBDA(xs,
+    IF(AND(1 = COLUMNS(xs), ISBLANK(xs)),
+        NA(),
+        INDEX(xs, 1, COLUMNS(xs))
+    )
+)
+
+
+TAILCOLS
+=LAMBDA(xs,
+    IF(1 < COLUMNS(xs),
+        INDEX(
+            xs,
+            1,
+            SEQUENCE(1, COLUMNS(xs) - 1, 2, 1)
+        ),
+        NA()
+    )
+)