Initial data commit

Task/Sorting-algorithms-Bubble-sort/CLU/sorting-algorithms-bubble-sort.clu

@@ -0,0 +1,36 @@
+% Bubble-sort an array in place.
+bubble_sort = proc [T: type] (a: array[T])
+              where T has lt: proctype (T,T) returns (bool)
+
+    bound_lo: int := array[T]$low(a)
+    bound_hi: int := array[T]$high(a)
+
+    for hi: int in int$from_to_by(bound_hi, bound_lo, -1) do
+        for i: int in int$from_to(bound_lo, hi-1) do
+            if a[hi] < a[i] then
+                temp: T := a[i]
+                a[i] := a[hi]
+                a[hi] := temp
+            end
+        end
+    end
+end bubble_sort
+
+% Print an array
+print_arr = proc [T: type] (a: array[T], w: int, s: stream)
+            where T has unparse: proctype (T) returns (string)
+    for el: T in array[T]$elements(a) do
+        stream$putright(s, T$unparse(el), w)
+    end
+    stream$putc(s, '\n')
+end print_arr
+
+start_up = proc ()
+    ai = array[int]
+    po: stream := stream$primary_output()
+    test: ai := ai$[7, -5, 0, 2, 99, 16, 4, 20, 47, 19]
+
+    stream$puts(po, "Before: ") print_arr[int](test, 3, po)
+    bubble_sort[int](test)
+    stream$puts(po, "After:  ") print_arr[int](test, 3, po)
+end start_up