Initial data commit

2023-07-01 11:58:00 -04:00 · 2023-07-01 11:58:00 -04:00 · f23f22d71c
commit f23f22d71c
parent 72d218235f
199087 changed files with 3378941 additions and 0 deletions
--- a/Task/Sorting-algorithms-Permutation-sort/Quackery/sorting-algorithms-permutation-sort.quackery
+++ b/Task/Sorting-algorithms-Permutation-sort/Quackery/sorting-algorithms-permutation-sort.quackery
@ -0,0 +1,29 @@
+  [ 1 swap times [ i 1+ * ] ] is !          (   n --> n )
+
+  [ [] unrot 1 - times
+      [ i 1+ ! /mod
+        dip join ] drop ]     is factoradic ( n n --> [ )
+
+  [ [] unrot witheach
+      [ pluck
+        rot swap nested join
+        swap ]
+    join ]                    is inversion  ( [ [ --> [ )
+
+  [ over size
+    factoradic inversion ]    is nperm      ( [ n --> [ )
+
+ [ true swap
+   behead swap
+   witheach
+     [ tuck > if
+       [ dip not conclude ] ]
+   drop ]                     is sorted     (   [ --> b )
+
+ [ 0
+   [ 2dup nperm
+     dup sorted not while
+     drop 1+ again ]
+   unrot 2drop ]              is sort       (   [ --> [ )
+
+  $ "beings" sort echo$