Initial data commit

Task/Vigen-re-cipher/D/vigen-re-cipher-1.d

@@ -0,0 +1,29 @@
+import std.stdio, std.string;
+
+string encrypt(in string txt, in string key) pure @safe
+in {
+    assert(key.removechars("^A-Z") == key);
+} body {
+    string res;
+    foreach (immutable i, immutable c; txt.toUpper.removechars("^A-Z"))
+        res ~= (c + key[i % $] - 2 * 'A') % 26 + 'A';
+    return res;
+}
+
+string decrypt(in string txt, in string key) pure @safe
+in {
+    assert(key.removechars("^A-Z") == key);
+} body {
+    string res;
+    foreach (immutable i, immutable c; txt.toUpper.removechars("^A-Z"))
+       res ~= (c - key[i % $] + 26) % 26 + 'A';
+    return res;
+}
+
+void main() {
+    immutable key = "VIGENERECIPHER";
+    immutable original = "Beware the Jabberwock, my son!" ~
+                         " The jaws that bite, the claws that catch!";
+    immutable encoded = original.encrypt(key);
+    writeln(encoded, "\n", encoded.decrypt(key));
+}

Task/Vigen-re-cipher/D/vigen-re-cipher-2.d

@@ -0,0 +1,26 @@
+import std.stdio, std.range, std.ascii, std.string, std.algorithm,
+       std.conv;
+
+immutable mod = (in int m, in int n) pure nothrow @safe @nogc =>
+    ((m % n) + n) % n;
+
+immutable _s2v = (in string s) pure /*nothrow*/ @safe =>
+    s.toUpper.removechars("^A-Z").map!q{ a - 'A' };
+
+string _v2s(R)(R v) pure /*nothrow*/ @safe {
+    return v.map!(x => uppercase[x.mod(26)]).text;
+}
+
+immutable encrypt = (in string txt, in string key) pure /*nothrow*/ @safe =>
+    txt._s2v.zip(key._s2v.cycle).map!q{ a[0] + a[1] }._v2s;
+
+immutable decrypt = (in string txt, in string key) pure /*nothrow*/ @safe =>
+    txt._s2v.zip(key._s2v.cycle).map!q{ a[0] - a[1] }._v2s;
+
+void main() {
+    immutable key = "Vigenere Cipher!!!";
+    immutable original = "Beware the Jabberwock, my son!" ~
+                         " The jaws that bite, the claws that catch!";
+    immutable encoded = original.encrypt(key);
+    writeln(encoded, "\n", encoded.decrypt(key));
+}