Sync

Task/Identity-matrix/NetRexx/identity-matrix-1.netrexx

@@ -0,0 +1,19 @@
+/* NetRexx ************************************************************
+* show identity matrix of size n
+* I consider m[i,j] to represent the matrix
+* 09.07.2013 Walter Pachl (translated from REXX Version 2)
+**********************************************************************/
+options replace format comments java crossref symbols binary
+
+Parse Arg n .
+If n='' then n=5
+Say 'Identity Matrix of size' n '(m[i,j] IS the Matrix)'
+m=int[n,n] -- Allocate 2D square array at run-time
+Loop i=0 To n-1 -- Like Java, arrays in NetRexx start at 0
+  ol=''
+  Loop j=0 To n-1
+    m[i,j]=(i=j)
+    ol=ol m[i,j]
+    End
+  Say ol
+  End

Task/Identity-matrix/NetRexx/identity-matrix-2.netrexx

@@ -0,0 +1,37 @@
+/* NetRexx */
+options replace format comments java crossref symbols nobinary
+
+runSample(arg)
+return
+
+-- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
+method createIdMatrix(n) public static
+  DIM_ = 'DIMENSION'
+  m = 0 -- Indexed string to hold matrix; default value for all elements is zero
+  m[DIM_] = n
+  loop i = 1 to n -- NetRexx indexed strings don't have to start at zero
+    m[i, i] = 1   -- set this diagonal element to 1
+    end i
+  return m
+
+-- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
+method displayIdMatrix(m) public static
+  DIM_ = 'DIMENSION'
+  if \m.exists(DIM_) then signal RuntimeException('Matrix dimension not set')
+  n = m[DIM_]
+  loop i = 1 to n
+    ol = ''
+    loop j = 1 To n
+      ol = ol m[i, j]
+      end j
+    say ol
+    end i
+  return
+
+-- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
+method runSample(arg) public static
+  parse arg n .
+  if n = '' then n = 5
+  say 'Identity Matrix of size' n
+  displayIdMatrix(createIdMatrix(n))
+  return